// MovieClip: マウスポインタに追随するインスタンス
// MovieClipアクション
onClipEvent (load) {
  var nDeceleration = 0.2;   // 減速率(0から1の間の小数値)
}
onClipEvent (enterFrame) {
  _x += _xmouse*nDeceleration;
  _y += _ymouse*nDeceleration;
}

[*1] 減速のアニメーションについては、F-siteセミナー「MovieClipのターゲットパスとプロパティ」およびFlash Power Session 2004 in Osaka「ActionScript 6つのテクニック」の「4. イーズアウトの公式」参照

// MovieClip: マウスポインタに追随するインスタンス
// 第1フレームアクション
var nDeceleration = 0.2;
function onEnterFrame() {
  _x += _xmouse*nDeceleration;
  _y += _ymouse*nDeceleration;
}

[*2] 以下のふたつのfunction(関数)定義は、ほぼ同じ意味。

function onEnterFrame() { }

this.onEnterFrame = function() { }

// MovieClip: マウスポインタに追随するインスタンス
// 第1フレームアクション
import flash.events.Event;   // Eventクラスをimport
var nDeceleration:Number = 0.2;
// イベントリスナーへの登録
addEventListener(Event.ENTER_FRAME, myEnterFrame);   // [*5]
function myEnterFrame(eventObject:Event):void {
  x += mouseX*nDeceleration;
  y += mouseY*nDeceleration;
}

[*3] MovieClip._xmouse/MovieClip._ymouseプロパティは、DisplayObject.mouseX/DisplayObject.mouseYプロパティに変わる。

[*4] function(関数)の戻り値がないときActionScript 2.0で使われたVoid型は、ActionScript 3.0では小文字で始まるvoidになるので注意する必要がある。

[*5] Event.ENTER_FRAMEは定数で、文字列"enterFrame"を返す。したがって、EventDispatcher.addEventListener()メソッドの第1引数に、文字列"enterFrame"を直接指定してもよい。

// ActionScript 2.0クラス定義ファイル: MyClass.as
class MyClass extends MovieClip {
  var nDeceleration:Number = 0.2;
  function onEnterFrame():Void {
    _x += _xmouse*nDeceleration;
    _y += _ymouse*nDeceleration;
  }
}

[*6] [ライブラリ]でMovieClipシンボルを選択し、オプションポップアップメニューから[プロパティ]を選ぶ。[シンボルプロパティ]ダイアログボックスの[AS 2.0クラス]にActionScript 2.0クラスを指定する(図002)。

図002■[シンボルプロパティ]ダイアログボックス

[AS 2.0クラス]にActionScript 2.0クラスを指定する

// ActionScript 3.0クラス定義ファイル: MyClass.as
package {
  import flash.display.MovieClip
  import flash.events.Event;
  public class MyClass extends MovieClip {
    var nDeceleration:Number = 0.2;
    // コンストラクタ関数
    function MyClass() {
      addEventListener(Event.ENTER_FRAME, myEnterFrame);
    }
    function myEnterFrame(eventObject:Event):void {
      x += mouseX*nDeceleration;
      y += mouseY*nDeceleration;
    }
  }
}