import flash.filters.BlurFilter;
var myBlur:BlurFilter = new BlurFilter();
this.filters = [myBlur];

BlurFilter(水平方向ぼかし, 垂直方向ぼかし, クォリティ)
指定した設定でBlurFilterインスタンスを生成する。クォリティは整数で、通常1から3までの値を使う(数値が大きいほどぼけ幅も大きい。0はぼかしなし)。デフォルト値(引数省略時の値)はぼかし量が4、クォリティは1。

// タイムライン: _root
// [ライブラリ]にリンケージ識別子"Pen"を設定したMovieClipが格納
// 第1フレームアクション
var nAmount:Number = 6;
var menus_array:Array = new Array();
var oInitObject:Object = new Object();
oInitObject.nRadiusX = 100;
oInitObject.nRadiusY = 20;
oInitObject.nCenterX = Stage.width/2;
oInitObject.nCenterY = Stage.height/2;
for (var i:Number = 0; i<nAmount; ++i) {
  var target_mc:MovieClip = this.attachMovie("Pen", "my"+i+"_mc", i, oInitObject);
  target_mc.nRadian = i*360/nAmount/180*Math.PI;
  menus_array.push(target_mc);
}
this.onEnterFrame = function():Void {
  xRotateAll(2/180*Math.PI);
};
function xRotateAll(nRadian:Number):Void {
  var nLength:Number = menus_array.length;
  for (var i:Number = 0; i<nLength; ++i) {
    menus_array[i].xRotate(nRadian);
  }
}

// MovieClip: リンケージ識別子"Pen"
// 第1フレームアクション
import flash.filters.BlurFilter;
var nMyDepth:Number = this.getDepth();
this.xRotate(0);
function xRotate(nTheta:Number):Void {
  nRadian += nTheta;
  var nUnitX:Number = Math.cos(nRadian);
  var nUnitY:Number = Math.sin(nRadian); // -1 ≦ nUnitY ≦ 1
  _x = nRadiusX*nUnitX+nCenterX;
  _y = nRadiusY*nUnitY+nCenterY;
  _xscale = 100*nUnitY;
  // _alpha = 50*(nUnitY+1)/2+50;
  var nBlur:Number = 4*(-nUnitY+1)/2; // 0 ≦ nUnitY ≦ 4
  // BlurFilterインスタンス生成
  var myBlur:BlurFilter = new BlurFilter(nBlur, nBlur/2);
  // MovieClip.filtersプロパティ設定
  this.filters = [myBlur];
  var nDepth = (nUnitY>0 ? nMyDepth+100 : nMyDepth);
  this.swapDepths(nDepth);
}

[*1] ベースにした.flaファイルは、[Flash 8アプリケーション]/Samples and Tutrials/Samples/ActionScript/Filters/Filters.fla。

import flash.display.BitmapData;
var myBitmapData:BitmapData = BitmapData.loadBitmap("Pen");
var _mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
_mc.attachBitmap(myBitmapData, _mc.getNextHighestDepth());

BitmapData.loadBitmap(リンケージ識別子)
リンケージ識別子が設定されたビットマップをロードして、新しいBitmapDataインスタンスを作成する。

MovieClip.attachBitmap(BitmapDataインスタンス, 深度)
指定されたBitmapDataインスタンスのイメージを、MovieClipに設定する。

import flash.display.BitmapData;
import flash.geom.Point;
var myBitmapData:BitmapData = BitmapData.loadBitmap("Pen");
var _mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
_mc.attachBitmap(myBitmapData, _mc.getNextHighestDepth());
var nRandom:Number;
_mc.onPress = function() {
  nRandom = Math.floor(Math.random()*10);
  this.onEnterFrame = xDissolve;
};
var nTotalDissolved:Number = 0;
var nTotalPixels:Number = myBitmapData.width*myBitmapData.height;
var nDissolving:Number = 30;
var zeroPoint:Point = new Point(0, 0);
function xDissolve() {
  nRandom = myBitmapData.pixelDissolve(myBitmapData, myBitmapData.rectangle, zeroPoint, nRandom, nDissolving, 0x00FFFFFF);
  nTotalDissolved += nDissolving;
  if (nTotalDissolved>=nTotalPixels) {
    delete this.onEnterFrame;
  }
  nDissolving = Math.floor(nDissolving*1.1);
}

BitmapData.pixelDissolve(ソースBitmapData, ソース矩形領域, 左上隅Point, ランダム値, ピクセル数, カラー値)
ソースイメージを、指定したカラー値でディゾルブする。ターゲットのBitmapDataと異なるソースイメージを指定すれば、ターゲットからソースへのディゾルブも可能。

ユニークなランダム値が返されるので、連続したディゾルブには、その値をつぎの呼出し時に引数として渡す。

除数   1

バイアス   128

ConvolutionFilter(列数, 行数, コンボリューション行列, 除数, バイアス)
コンボリューション行列を適用してピクセル単位のイメージ処理を行う。

// MovieClip this;
import flash.filters.ConvolutionFilter;
import flash.display.BitmapData;
var _mc:MovieClip = this.createEmptyMovieClip("image_mc", this.getNextHighestDepth());
_mc.attachBitmap(BitmapData.loadBitmap("Pen"), _mc.getNextHighestDepth());
// ConvolutionFilter引数設定
var nMatrixX:Number = 5;   // 列数
var nMatrixY:Number = 5;   // 行数
// コンボリューション行列を配列として作成
var matrix_array:Array = new Array();
// 最終的に作成される25エレメントの配列[*2]
// [0,0,0,0,0,0,1,1,0,0,0,1,0,-1,0,0,0,-1,-1,0,0,0,0,0,0]
matrix_array = matrix_array.concat([0, 0, 0, 0, 0]);
matrix_array = matrix_array.concat([0, 1, 1, 0, 0]);
matrix_array = matrix_array.concat([0, 1, 0, -1, 0]);
matrix_array = matrix_array.concat([0, 0, -1, -1, 0]);
matrix_array = matrix_array.concat([0, 0, 0, 0, 0]);
var nDivisor:Number = 1;   // 除数
var nBias:Number = 128;   // バイアス
_mc.onPress = function():Void {
  var myConvolution:ConvolutionFilter = new ConvolutionFilter(nMatrixX, nMatrixY, matrix_array, nDivisor, nBias);
  this.filters = [myConvolution];
};

[*2] ConvolutionFilter()に指定するコンボリューション行列は行数(5)×列数(5)の総エレメント数(25)を羅列した配列なので、Array.concat()メソッドを使って、RGBA各カラー値ごとの5エレメントからなる4つの配列をひとつに連結している。

Matrix.translate(tx, ty)
水平方向にtxピクセル、垂直方向にtyピクセル平行移動する。

Matrix.scale(a, d)
水平方向にa倍、垂直方向にd倍の拡大・縮小を行う。

Matrix.rotate(θ)
角度θ(ラジアン)の回転を行う。変換行列のプロパティ4つの値を、a:cosθ、b:sinθ、c:-sinθ、d:cosθに設定するのと同じ結果になる。

// タイムライン: _root
// 第1フレームアクション
// 変形するMovieClip: _root.my_mc
import flash.geom.Matrix;
import flash.geom.Point;
// Pointインスタンスで指定された3頂点に合わせてMovieClipを変形する
// MovieClip.transform.matrixのプロパティ値を計算して設定
function xTransformMovieClipPoints(_mc:MovieClip, point0:Point, point1:Point, point2:Point):Void {
  var myMatrix:Matrix = _mc.transform.matrix;
  var contents_mc:MovieClip = _mc.contents;
  var nWidth:Number = contents_mc._width;
  var nHeight:Number = contents_mc._height;
  var point1_0:Point = point0.subtract(point1);
  var point1_2:Point = point2.subtract(point1);
  myMatrix.tx = point1.x;
  myMatrix.ty = point1.y;
  myMatrix.a = (point1_0.x)/nWidth;
  myMatrix.b = (point1_0.y)/nWidth;
  myMatrix.c = (point1_2.x)/nHeight;
  myMatrix.d = (point1_2.y)/nHeight;
  _mc.transform.matrix = myMatrix;
}
// 3頂点の座標を取得してxTransformMovieClipPoints()に渡す
// ドラッグした頂点のMovieClipから呼出される
function xTransform() {
  var point0:Point = new Point(point0_mc._x, point0_mc._y);
  var point1:Point = new Point(point1_mc._x, point1_mc._y);
  var point2:Point = new Point(point2_mc._x, point2_mc._y);
  xTransformMovieClipPoints(my_mc, point0, point1, point2);
}

// MovieClip: ドラッグする頂点
// 第1フレームアクション
function onPress():Void {
  this.startDrag();
}
function onRelease():Void {
  xOnRelease();
}
function onReleaseOutside():Void {
  xOnRelease();
}
function xOnRelease():Void {
  this.stopDrag();
  _root.xTransform()
}

[*3] 3Dの座標を扱うクラスは、Flash 8にも存在しない。したがって、座標の管理はスクリプトで行い、3次元での回転も独自に計算する必要がある。3Dの座標の扱いについては、以下のURLが参考になる。

「3D基礎知識」「3D座標変換」「Affine変換とAffine行列の関係」「ベクトルと行列」「Javaソース付き 3Dプログラミング入門」