// MovieClip: アニメーションするインスタンス
// MovieClipアクション
onClipEvent (load) {
  var nCenterX:Number = Stage.width/2;
  var nCenterY:Number = Stage.height/2;
  var nRadian:Number = 0;
  var nRadiusX:Number = 100;
  var nRadiusY:Number = 60;
  _x = nCenterX;
  _y = nCenterY;
}
onClipEvent (enterFrame) {
  nRadian += 0.1;
  _x = nCenterX+nRadiusX*Math.cos(nRadian);
}

[*1] Flash Player 9およびActionScript 3.0の概要については、「AdobeのFlash担当者に訊く - Flash Player 9とActionScript 3.0何が変わる?」(06/06/20)を参照。

[*2] スクリプトはActionScript 1.0のFlash 5スタイルを採っているものの、ActionScript 2.0の「厳密な型指定」を用いている。

「厳密な型指定」について詳しくは、Flash 8オンラインヘルプの「データ型の割り当てと厳密な型指定について」参照。

[*3] 直線上におけるバネのような振動(単振動)は、振動の中心をa、振幅をbとし、振動のスピードを決め、直線的に変化する変数をθとすると、振動する位置xはつぎの式で表せる。

x = a + b×cos(θ)

なお、単振動などの運動については、Wikipedia「振動運動」が詳しい。

// MovieClip: アニメーションするインスタンス
// 第1フレームアクション
var nCenterX:Number = Stage.width/2;
var nCenterY:Number = Stage.height/2;
var nRadian:Number = 0;
var nRadiusX:Number = 100;
var nRadiusY:Number = 60;
_x = nCenterX;
_y = nCenterY;
function onEnterFrame():Void {
  nRadian += 0.1;
  _x = nCenterX+nRadiusX*Math.cos(nRadian);
}

[*4] スクリプト002のイベントハンドラメソッドMovieClip.onEnterFrameイベントハンドラメソッドは、つぎのように名前のない関数で定義することもできる。

this.onEnterFrame = function():Void {
  // ステートメント
};

なお、名前のない関数については、「名前のない関数(匿名関数/関数リテラル)」を参照。

// MovieClip: アニメーションするインスタンス
// 第1フレームアクション
var nCenterX:Number = stage.stageWidth/2;
var nCenterY:Number = stage.stageHeight/2;
var nRadian:Number = 0;
var nRadiusX:Number = 100;
var nRadiusY:Number = 60;
x = nCenterX;
y = nCenterY;
addEventListener("enterFrame", enterFrame);
function enterFrame(eventObject:Event):void {
  nRadian += 0.1;
  x = nCenterX+nRadiusX*Math.cos(nRadian);
}

[*5] EventDispatcher.addEventListener()メソッドについて詳しくは、「EventDispatcher.addEventListener()メソッド」を参照。

[*6] ActionScript 1.0/2.0では、引数が渡されても、関数に引数を設定しなければ、受取れないだけ。しかし、ActionScript 3.0では、渡されるのと同じ数の引数を関数に定義しないと、エラーが発生する。

// MovieClip: アニメーションするインスタンス
// 第1フレームアクション
import flash.display.MovieClip;
import flash.events.Event;
var nCenterX:Number = stage.stageWidth/2;
var nCenterY:Number = stage.stageHeight/2;
var nRadian:Number = 0;
var nRadiusX:Number = 100;
var nRadiusY:Number = 60;
x = nCenterX;
y = nCenterY;
addEventListener(Event.ENTER_FRAME, enterFrame);
function enterFrame(eventObject:Event):void {
  nRadian += 0.1;
  // x = nCenterX+nRadiusX*Math.cos(nRadian);   →メインタイムラインへ
}

// タイムライン: _level0
// 第1フレームアクション
import flash.display.MovieClip;
import flash.events.Event;
my_mc.addEventListener(Event.ENTER_FRAME, enterFrame);
function enterFrame(eventObject:Event):void {
  my_mc.x = my_mc.nCenterX+my_mc.nRadiusX*Math.cos(my_mc.nRadian);
}

[*7] importステートメントの仕様は、ActionScript 2.0とは一部変わっている。詳しくは、F-site「importの使い方が変わった」およびそこに引用した資料を参照。

// ActionScript 3.0クラス定義ファイル: Initialize.as
package {
  import flash.display.MovieClip;
  import flash.events.Event;
  public class Initialize extends MovieClip {
    var nCenterX:Number = stage.stageWidth/2;
    var nCenterY:Number = stage.stageHeight/2;
    var nRadian:Number = 0;
    var nRadiusX:Number = 100;
    var nRadiusY:Number = 60;
    function Initialize() {
      x = nCenterX;
      y = nCenterY;
      addEventListener(Event.ENTER_FRAME, enterFrame);
    }
    function enterFrame(eventObject:Event):void {
      nRadian += 0.1;
    }
  }
}

// ActionScript 3.0クラス定義ファイル: WaveX.as
package {
  import flash.display.MovieClip;
  import flash.events.Event;
  class WaveX {
    var my_mc:MovieClip;
    function WaveX(target_mc) {
      my_mc = target_mc;
      my_mc.addEventListener(Event.ENTER_FRAME, enterFrame);
    }
    function enterFrame(eventObject:Event):void {
      my_mc.x = my_mc.nCenterX+my_mc.nRadiusX*Math.cos(my_mc.nRadian);
    }
  }
}

// タイムライン: _level0
// 第1フレームアクション
var myWaveX:WaveX = new WaveX(my_mc);

[*8] packageについて、詳しくは「package定義キーワード」を参照してほしい。

[*9] classとpublicについては、それぞれ「class定義キーワード」および「public属性キーワード」をご覧いただきたい。

[*10] クラスWaveXは、MovieClipシンボルに設定しないので、public属性を指定する必要はない。また、WaveX自体はMovieClipクラスを継承しなくてよい。

[*11] 実際には、WaveXのインスタンスを参照してアクセスするプロパティやメソッドは定義していないので、インスタンスを格納する左辺の変数はなくてもよい。

new WaveX(my_mc);

// ActionScript 3.0クラス定義ファイル: WaveY.as
package {
  import flash.display.MovieClip;
  import flash.events.Event;
  class WaveY {
    var my_mc:MovieClip;
    function WaveY(target_mc) {
      my_mc = target_mc;
      my_mc.addEventListener(Event.ENTER_FRAME, enterFrame);
    }
    function enterFrame(eventObject:Event):void {
      my_mc.y = my_mc.nCenterY+my_mc.nRadiusY*Math.sin(my_mc.nRadian);
    }
  }
}

// ActionScript 3.0クラス定義ファイル: DirectionX.as
package {
  import flash.display.MovieClip;
  import flash.events.Event;
  class DirectionX {
    var my_mc:MovieClip;
    function DirectionX(target_mc) {
      my_mc = target_mc;
      my_mc.addEventListener(Event.ENTER_FRAME, enterFrame);
    }
    function enterFrame(eventObject:Event):void {
      my_mc.scaleX = -Math.sin(my_mc.nRadian);
    }
  }
}

// ActionScript 3.0クラス定義ファイル: DirectionY.as
package {
  import flash.display.MovieClip;
  import flash.events.Event;
  import flash.filters.BlurFilter;
  class DirectionY {
    var my_mc:MovieClip;
    function DirectionY(target_mc) {
      my_mc = target_mc;
      my_mc.addEventListener(Event.ENTER_FRAME, enterFrame);
    }
    function enterFrame(eventObject:Event):void {
      var nBlur:Number = -(Math.sin(my_mc.nRadian)-1);
      var myBlur:BlurFilter = new BlurFilter(nBlur*4, nBlur);
      my_mc.filters = [myBlur];
    }
  }
}

// タイムライン: _level0
// 第1フレームアクション
var myWaveX:WaveX = new WaveX(my_mc);
var myWaveY:WaveY = new WaveY(my_mc);
var myDirectionX:DirectionX = new DirectionX(my_mc);
var myDirectionY:DirectionY = new DirectionY(my_mc);

[*12] X軸方向の単振動をcos、Y方向の単振動をsinで定義して同期させると、楕円運動になる。なお、「はじめの一歩のアクションスクリプト」「4. Mathクラスを使う」参照。

[*13] DisplayObject.scaleXプロパティも、MovieClip._xscaleと同じく、マイナス値は水平方向の向きを反転させる。スクリプト010で、Math.sin()の戻り値にマイナスをつけているのは、もとのMovieClipインスタンスが右向きのためである。

[*14] スクリプトによるフィルタの適用については、「新機能とスクリプティング」「1. ぼかしとドロップシャドウフィルタ」参照。

// ActionScript 3.0クラス定義ファイル: MyButton.as
package {
  import flash.display.MovieClip;
  import flash.events.MouseEvent;
  public class MyButton extends MovieClip {
    function MyButton() {
      addEventListener(MouseEvent.CLICK, click);
    }
    function click(eventObject:MouseEvent):void {
      trace(this, "clicked");
    }
  }
}

// ActionScript 3.0クラス定義ファイル: MyButton.as
package {
  import flash.display.MovieClip;
  import flash.events.MouseEvent;
  public class MyButton extends MovieClip {
    function MyButton() {
      addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);
      addEventListener(MouseEvent.CLICK, click);
    }
    function mouseDown(eventObject:MouseEvent):void {
      trace(this, "pressed");
    }
    function click(eventObject:MouseEvent):void {
      trace(this, "clicked");
    }
  }
}

[*15] 厳密にはマウスイベントはMovieClipが継承するInteractiveObjectクラスに定義されており、MouseEventクラスはそのイベントを指定する文字列の定数を定める。詳しくは、「マウスイベント」を参照されたい。

[*16] ActionScript 3.0のtrace()関数は、1.0/2.0から仕様が拡張され、複数の引数を指定できる。

// ActionScript 3.0クラス定義ファイル: MyButton.as
package {
  import flash.display.MovieClip;
  import flash.events.MouseEvent;
  public class MyButton extends MovieClip {
    public var onPress:Function;
    public var onRelease:Function;
    function MyButton() {
      addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);
      addEventListener(MouseEvent.CLICK, click);
    }
    function mouseDown(eventObject:MouseEvent):void {
      onPress();
    }
    function click(eventObject:MouseEvent):void {
      onRelease();
    }
  }
}

// タイムライン: _level0
// フレームアクション
my_mc.onPress = function() {
  trace("press");
};
my_mc.onRelease = function() {
  trace("release");
};

// ActionScript 3.0クラス定義ファイル: MyButton.as
package {
  import flash.display.MovieClip;
  import flash.events.MouseEvent;
  public class MyButton extends MovieClip {
    public var onPress:Function;
    public var onRelease:Function;
    public var onReleaseOutside:Function;
    function MyButton() {
      addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);
    }
    function mouseDown(eventObject:MouseEvent):void {
      onPress();
      addEventListener(MouseEvent.MOUSE_UP, mouseUp);
      stage.addEventListener(MouseEvent.MOUSE_UP, mouseUp2);
    }
    function mouseUp(eventObject:MouseEvent):void {
      onRelease();
      removeEventListener(MouseEvent.MOUSE_UP, mouseUp);
      stage.removeEventListener(MouseEvent.MOUSE_UP, mouseUp2);
    }
    function mouseUp2(eventObject:MouseEvent):void {
      onReleaseOutside();
      removeEventListener(MouseEvent.MOUSE_UP, mouseUp);
      stage.removeEventListener(MouseEvent.MOUSE_UP, mouseUp2);
    }
  }
}

// タイムライン: _level0
// フレームアクション
my_mc.onPress = function() {
  trace("press");
};
my_mc.onRelease = function() {
  trace("release");
};
my_mc.onReleaseOutside = function() {
  trace("releaseOutside");
};

[*17] MouseEvent.DOUBLE_CLICKの扱いについては、F-site「doubleClickを受取る」を参照。

[*18] このクラスMyButtonの定義は、マウスイベントの扱いを示すための最小限のサンプルである。たとえば、テスト用のスクリプト018で、イベントハンドラメソッドのいずれかが設定されてない場合、クラスのメソッドから呼出す関数が存在しない旨のエラーになる。こうした対処も施したサンプルは、「EventDispatcher.addEventListener()メソッド」のスクリプト001になる。

[*19] 前出注[*1]の記事のほか、「ActionScript 3デビューセミナー - その真価を探る」(06/7/28)を参考にしてほしい。