[*1] JavaのサンプルプログラムをActionScript 3.0に書替えた例は、F-site「Observerパターンのサンプルプログラム」でご紹介しています。

// インターフェイス定義ファイル: IIntervalGenerator.as
// イベントを配信するクラスに実装

1. package {
2.   public interface IIntervalGenerator {
       // 配信側クラスに必要なメソッド
3.     function addListener(observer:IObserver):void;
4.     function removeListener(observer:IObserver):void;
5.     function dispatchEvent():void;
       // サンプルとして加えたメソッド
6.     function start():void;
7.   }
8. }

// インターフェイス定義ファイル: IObserver.as
// イベントを受信するクラスに実装

1. package {
2.   public interface IObserver {
3.     function timer():void;
4.   }
5. }

// ActionScript 3.0クラス定義ファイル: Interval.as
// イベントを配信する

1. package {
2.   import flash.utils.setInterval;
3.   import flash.utils.clearInterval;
4.   public class Interval implements IIntervalGenerator {
5.     private var listeners:Vector.<IObserver> = new Vector.<IObserver>();
6.     private var interval:uint;
7.     private var id:uint;
8.     public function Interval(myInterval:uint = 100) {
9.       interval = myInterval;
10.     }
11.     public function addListener(listener:IObserver):void {
12.       listeners.push(listener);
13.     }
14.     public function removeListener(listener:IObserver):void {
15.       var nLength:uint = listeners.length;
16.       for (var i:uint = 0; i < nLength; i++) {
17.         if (listeners[i] == listener) {
18.           listeners.splice(i, 1);
19.           break;
20.         }
21.       }
22.     }
23.     public function dispatchEvent():void {
24.       var nLength:uint = listeners.length;
25.       for (var i:uint = 0; i < nLength; i++) {
26.         var listener:IObserver = listeners[i];
27.         listener.timer();
28.       }
29.     }
30.     public function start():void {
31.       clearInterval(id);
32.       id = setInterval(dispatchEvent, interval);
33.     }
34.   }
35. }

// ActionScript 3.0クラス定義ファイル: Listener.as
// イベントを受信する

1. package {
2.   import flash.display.MovieClip;
3.   public class Listener extends MovieClip implements IObserver {
4.     public var onTimer:Function;
5.     public function Listener() {}
6.     public function timer():void {
7.       if (onTimer) {
8.         onTimer();
9.       }
10.     }
11.   }
12. }

// [クラス]にListenerを設定したMovieClipシンボル
// フレームアクション

1. var nSpeed:Number = 5;
2. var nStageWidth:Number = stage.stageWidth;
3. var nStageCenter:Number = nStageWidth / 2;
4. var myInterval:Interval = new Interval();
5. onTimer = xScroll;
6. myInterval.addListener(this);
7. myInterval.start();
8. function xScroll():void {
9.   x += nSpeed;
10.   if (x > nStageWidth) {
11.     x -= nStageWidth;
12.   } else if (Math.abs(x - nStageCenter) < nSpeed) {
13.     x = nStageCenter;
14.     onTimer = xRotate;
15.   }
16. }
17. function xRotate():void {
18.   rotation += nSpeed;
19.   if (Math.abs(rotation) < nSpeed) {
20.     rotation = 0;
21.     onTimer = xScroll;
22.   }
23. }

[*2] 同じオブザーバーのインスタンスを複数登録する場合について、それをとくに避ける処理は加えていません。

[*3] if条件に直接Function型のプロパティを指定すると、コンパイラ警告#3553が告げられます。

Warning: 3553: Boolean型が必要なところに関数値が使用されています。この関数参照の後に括弧()がない可能性があります。

関数を呼出していない旨の警告ですので、あえて呼出さないこの処理では問題はありません。気になるようでしたら、値をBoolean型に変換してください。

public function timer():void {   // if (onTimer) {   if (Boolean(onTimer)) {