[訳者注*1] ディスプレイリストについては、akihiro kamijo「DisplayObjectContainerクラス」をご参照ください。

[訳者注*2] SpriteとMovieClipの違いについては、akihiro kamijo「SpliteクラスとMovieClipクラス」をご参照ください。

package {
  import flash.display.Sprite;
  import flash.events.*;

  public class SpriteExample extends Sprite {
    private var size:uint  = 100;
    private var bgColor:uint = 0xFFCC00;

    public function SpriteExample() {
      var child:Sprite = new Sprite();
      child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
      child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
      draw(child);
      addChild(child);
    }

    private function mouseDownHandler(event:MouseEvent):void {
      trace("mouseDownHandler");
      var sprite:Sprite = Sprite(event.target);
      sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
      sprite.startDrag();
    }

    private function mouseUpHandler(event:MouseEvent):void {
      trace("mouseUpHandler");
      var sprite:Sprite = Sprite(event.target);
      sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
      sprite.stopDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
      trace("mouseMoveHandler");
      event.updateAfterEvent();
    }

    private function draw(sprite:Sprite):void {
      sprite.graphics.beginFill(bgColor);
      sprite.graphics.drawRect(0, 0, size, size);
      sprite.graphics.endFill();
    }
  }
}

[訳者注*3] [Control] > [Test Movie](ムービープレビュー)を行い、オレンジの正方形の上でマウスをクリックしてドラッグし、マウスボタンを放すと、それぞれのイベントに応じて呼出されたメソッドから"mouseDownHandler"、"mouseMoveHandler"、"mouseUpHandler"のテキストが[Output](出力)パネルに表示されます(図001)。

図001■マウス操作から発生するイベントに応じてメソッドが呼出される

メソッドを呼出すとその名前が出力される

[訳者注*4] SpriteExampleクラスは、MovieClipシンボルまたはFlashドキュメントに設定します。MovieClipシンボルに設定する場合には、[Symbol Properties](シンボルプロパティ)あるいは[Linkage Properties](リンケージプロパティ)のダイアログボックスで、[Class]にクラス名を入力します(図002)。

図002■ActionScript 3.0クラスをMovieClipの[Class]に設定

リンケージの[Class]にクラス名を入力する

Flashドキュメントに設定するには、ドキュメントに対して[Properties](プロパティ)インスペクタで[Document class]にクラス名を入力します図003()。

■ActionScript 3.0クラスをドキュメントの[Document class]に設定

[Properties]インスペクタで[Document class]にクラス名を入力する